アナクロなコンピューターエンジニアのつぶやき

IBM JX -- POST ERROR

Thu, 23 Apr 2026 21:45:00 +0900

せんだて、入手したIBM JXにアップスキャンコンバーターを経由してVGAディスプレイを接続したのですが、あの、本体起動直後のカラーの画面が表示されません。

BEEP音が2回しますので、POST(Power On Self Test)でハードウェア・エラーを検出しています。検出したエラーは、画面に表示されるのですが。そもそも、ディスプレーには何も映らないので、どうして良いのやら。

まず、アップスキャンコンバーターのロゴやメニューが表示されるので、コンバーターは生きています。更に、コンバーターは、"NO SIGNAL"と言ってきます。JXのディスプレーポートとコンバーター間の接続を再確認。間違いなし。

念の為、JXのディスプレーポート J15 の信号を確認したところ、以下のようでした。

PIN#	NAME	SIGNAL
1	GND
2	R	NO SIGNAL
3	-HSYNC	NO SIGNAL
4	-VSYNC	NO SIGNAL
5	H/-LSW	OK
6	I	OK
7	B	NO SIGNAL
8	GND
9	GND
10	G	NO SIGNAL
11	COLOR CLOCK	OK
12	+12V
13	DOT CLOCK	OK
14	AUDIO
15	GND

J15に出てくる信号は、このようになってます。

"I"や"H/-L SW"が出てきているので、IC69 74LS240は、生きてるでしょう。"I"はカスタムICのIC32 SX001から来る信号なのです。IC32も生きてるように感じます。

ということは、Display関連のテストとそれ以前のテストで、POSTが障害を検出したのは間違いないのですが、このままでは、場所を特定できません。

というわけで、POSTを読んでます。

ユーザーに優しくないシステム

Thu, 23 Apr 2026 09:00:00 +0900

私達は、日々、コンピューターを利用したシステムを使っています。パソコンや携帯電話、スマートフォンを使用しない日は、ないでしょう。それで使用する機能は何でしょうか？

ネットサーフィン。
インターネット・メールのやり取り。
youTubeで動画を視聴。
Xでつぶやく。
Amazon Prime Videoで名探偵コナンを視聴。
etc. ...

両手の指では数えられないほどあるでしょう。みなさん、それぞれの利用の仕方・楽しみ方があるでしょう。そして、大多数の方はインターネット・メールを利用していることと思います。私もこのAsahi-netのメール・アドレスだけでなく、auや他のメール・アドレスを持っています。実際に使っているのは一部だけですがね。

せんだて、auメールで痛い目にあいました。調べてみると、「ユーザーに優しくないシステム」が露わに。

ことの発端は、今年の1月下旬、なんの前触れもなく、多数の古いメールが削除されてしまったことです。調べてみると、 auメールにはサーバー側に保管してあるメールの件数と総データ量に制限があり、この制限を超えると、古いメールから必要数をメールサーバーが(強制的かつ)自動的に削除する仕様になっていることがわかりました。「容量の上限に近づいた」とか「メールを削除しますよ」と言ったお知らせはないのです。ユーザーは削除されてしまってから、この制限に達したことを知ることになります。せめて、「ゴミ箱」フォルダーのメール優先でやってくれれば、悲劇は減るでしょうに。

メールの管理は、ユーザーが行うことになってますが、自分のメールの総量を知る手段はありません。メールアプリは、そもそも、そのような機能が、iMAPにありませんので、知る由もなしです。

auが提供している「My au」アプリがあります。これで、データ通信量はわかりますが、メールの総量はわかりません。

この状況で、ユーザーは、いったい、いつ、不要なメールを削除すればよいのでしょうか？自分のメールの総量を知るすべがないので、わかりません。

iMAPによるメールの配信サービスですから、ユーザーが受信したメールは全てメールサーバー側にあります。「auメールのサーバーの管理業務は大変だろうなぁ」と感じてましたが、こんな仕様になっているとは。

更に調べてみると、同じauがサービスしている他のメールサービス「au-Oneメール」では、容量の上限に近づくとユーザーにお知らせが出ることになってます。「同じauなのに、同じようにお金払ってるのに、なんで違うの？」、理由を想像できません。メールサーバーの中身はほぼ同じと思いますが。

各ユーザーごとのメールの総量を定期的に調べる機能は、どちらのメールサーバにも備わっています。この機能がなければ、古いメールを削除する機能を動かすタイミングを知ることができません。ですので、あるユーザーのメール総量が限界に近づいていることをメールサーバーは確実に知ることができます。あとは、該当ユーザーにお知らせを出すだけです。これは、自動的にできます。このぐらいの気配りはできるでしょう。しかし、やらなかった。システム設計の基本構想の不備、「ユーザー視点の欠落」。致命的なミスです。ユーザーに知らせずに勝手に削除したら、何が起こるか、ユーザーはどんな反応をするかを　想像できなかったんでしょうね。「ユーザーに優しくないシステム」を作ってしまったね。

さて、このauメールサービスの容量制限は、緩和策があります。オプションの「Pontaパス」に入会すると、容量がほぼ倍増します。倍増するタイミングは、「Pontaパス」に加入したタイミングでは「なく」、 Webブラウザーで「Webメール」サイトにアクセスした時点です。このようにしている理由を想像できません。

いや、一つだけ想像できます。それは、メールサーバーの運用管理を楽したいからです。「Pontaパス」に入会した時点で制限を緩和する仕組みにすると、メールサーバーの物理的容量を頻繁に増量する必要が出てきそうです。これを逃げるために、「Webメール」をアクセスした時点で、初めて、容量制限を緩和することにしたのでしょう。「Pontaパス」に加入したユーザー全員が、容量緩和を目的で加入するわけではないでしょうからね。

ここにも、「ユーザーに優しくないシステム」の一面が見えます。

auメールのトラブルに見舞われてから3ヶ月、先日、添付のメールが、auから来ました。ほんの少し、auメールのメールサーバーでメールを削除するロジックを変更するようです。今頃か。これでも、まだまだ、不十分です。「ゴミ箱」フォルダーのメールを　優先して定期的に削除しても、メール総量に達することが、予想されます。やはり、ユーザーにメールの削除・整理を依頼する必要があるでしょう。付け焼き刃というか、焼け石に水、それとも、モグラ叩き。最小の費用でと考えたのでしょうが、これではねぇ。問題の解決には、至らないでしょう。無駄な費用を　費やしただけですね。「ユーザーに優しいシステム」という視点がない、「自分たちの都合最優先のシステム作り」をやめてください。

私事ですが、現役のとき、このような視点に基づいた基本計画・設計のシステム提案書をお客様に持っていったら、良くてゴミ箱に捨てられる、悪くすれば出入り禁止になってたね。実際に使用するお客様の視点で、システム基本計画・設計することを常に求められていたし、それは暗黙の了解事項だった。

クレームがあったら、ちょこっと修正してお茶を濁し、ほとぼりが冷めるのを待つ。無責任時代になったのか？

この前、若いauの社員と話す機会があったのだが、KDDIの前身、「国際電電」を知らなかった。昭和は遠くに成りにけりか。今が良ければ過去なんてかな。

ご参考のため、auからのメール(必要な部分のみ)掲載します。公式なメールだから、公開してもいいよね、auさん。

いま、読みなおして気づいたのだが、「自動削除される場合があります。」とあるが、これは、「自動削除されます。」の間違いなのでは？それより、「ゴミ箱」フォルダー内のメールを自動削除する機能は、以前からあったっけ？「#90日以前の受信メール」フォルダーにあるメールを自動削除する機能は、あったと思うが。ユーザーを煙に巻く、いやな感じ。


========================= auからのメール 関連部分のみ (ここから) =============================
差出人: auからの重要なお知らせ 
日時: 2026年4月21日 10:18:06 JST
宛先: ########@ezweb.ne.jp
件名: auメールご利用のお客さまへの重要なお知らせ

いつもauメールをご利用いただきありがとうございます。

このたび、auメールをより安心・快適にご利用いただくため、以下2点をご案内いたします。

１．「迷惑メールおまかせ規制」の判定精度向上
２．auメールサーバのゴミ箱内メールの自動削除仕様改善

１．「迷惑メールおまかせ規制」の判定精度向上について

((((( 省略 By Kida ))))

２．auメールサーバのゴミ箱内メールの自動削除仕様の改善
「ゴミ箱」に移動したメールがたまり続けると、容量不足が影響し、受信ボックス内のメールが先に自動削除される場合があります。
このたびメールサービスを、より快適にご利用いただけるよう、2026年6月より順次、auメールサーバのゴミ箱内メールの自動削除仕様を改善します。

■ 変更内容
「ゴミ箱」フォルダにあるメールのうち、受信日から45日を経過したメールを、サーバから自動的に削除します。
本仕様変更の対象のお客さまや開始時期などの詳細・最新情報については、以下のURLよりご確認ください。
> https://www.au.com/mobile/service/email/

--------------------------------
■ お問い合わせ
チャット
受付時間　AI：24時間/年中無休
（コミュニケーター：9:00-20:00）
au：https://kddi-l.jp/Ika
========================= auからのメール 関連部分のみ (ここまで) =============================

とうとう、武器商人国になってしまった。

Wed, 22 Apr 2026 21:10:00 +0900

この場に、このようなことを書き込むことに、非常に強い悲しみを感じる。

あらゆる兵器、殺傷能力のありなしに関わらず、よその国に輸出出来ることになったと言う。国会の承認不要、つまり、最低限の歯止めが無くなった。

私たちは、好むと好まざるに関わらず、殺人の片棒を担ぐ事になる。

私たちは、これを容認して良いのか？

防衛産業の保護育成は、国の安全保障に必要なのだと言う。防衛産業の基礎になる多くの基礎技術は、民間転用できると言われてきた。

これは事実だったか？

その技術開発に注ぎ込まれる費用、労力は、莫大である。防衛予算を見れば判る。民間での技術開発におけるそれは、足元にも及ばない。

この産業は、一部の上級民だけに必要で、ほとんどの国民には不要な産業じゃないか？

なぜ、高市早苗は、私たちに、こんなにも不安を与えるのだ？止めてくれ。政治の世界から、退場してくれ。

今年も、クリスマスにはこの曲を楽しく聴きたい。HAPPY XMAS(War Is Over) JOHN & YOKO/THE PLASTIC ONO BAND

書いてたら、何故か、涙が出てきた。

IBM JX

Fri, 20 Mar 2026 17:00:00 +0900

IBM JX 本体を比較的安価に、入手できました。

内容は、

メモリー 128KB (本体 64KB、64KB メモリーカード)
2 Diskette Drive
拡張表示カード

です。

JX 本体の上にある本は、

「DOSの内部構造とプログラムインターフェイス N:SC18-2016-0」
「テクニカル・リファレンス N:SY18-2104-1」

です。貴重な資料です。

電源は、入りました。BEEP音が2回鳴ったので、ハードウェアーエラーを検出したみたいです。

まずは、ディスプレーとキーボードの接続からでしょうか。

デジタル RGB ディスプレーを入手は、大変でしょうから、今時のVGAディスプレーの接続を検討します。

JX用純正キーボードを望む事も無理ですから、今時のPS/2接続のキーボードを流用を検討します。

これ以外にも、やってみたいことが。

XT-IDE を移植したい
384KB 拡張メモリーアダプターを追加したい
拡張ボックスを追加したい

などなど。

どこまで、できるかな？　当分、楽しめそうです。

GAL Writerの制作

Mon, 14 Apr 2025 17:30:46 +0900

ハードウェアの制作にGALを使用できると、とても便利です。特にアドレスデコーダーの類などは、とてもすっきりしますし、後からの変更も簡単にできますので、重宝します。これまで、いくつかの機器の制作で使用してきました。

GALを作成するには、PALASMでヒューズデータを作成し、XGecuのTL866 II Plus で書き込みをしていました。

これはこれで、いいのですが、PALASMはDOSのプログラムで、 TL866II PlusはWindosのコントルールプログラムでした。そうです。ヒューズデータのやりとりがめんどうだったのです。できれば、DOS環境だけで完結したく思ってました。

調べてみると、GAL Writerの制作例をいくつか発見できました。その中でも、 ELM氏の発表なされた「お手GAL」は、以前より気にかけていたのですが、とてもシンプルで、 DOSの環境で使うことができ、私の悩みを解決するものです。思い切って制作することにしました。 ELM氏の「お手GAL」はここにありますのでご参照ください。

実際の制作にあったって、手持ちの部品を優先して使用したので、古い大型の部品やオーバースッペクの部品が見受けられます。また、抵抗内蔵のディジタルトランジスタは、抵抗と手持ちのトランジスタで構成しました。デバッグをしていて、プリンタポートの出力電圧が低かったのでバッファーを追加する必要がでてしまいましたが、大きめのボードだったのでいれることができました。

これが、完成した私の「お手GAL GAL Writer」です。

これで、16V8,20V8,22V10をプログラムできます。今後とも、重宝しそうです。

高速キャリージェネレター付き8ビット加算・減算器の製作

Thu, 06 Feb 2025 21:36:40 +0900

高速キャリージェネレター付き8ビット加算・減算器の製作

デジタル回路の学び直しをしています。テキストは、大川喜邦著「デジタル回路」です。組合せ回路の部分が終わりました。組合せ回路のまとめとして、高速キャリージェネレーター付きの8ビット加算・減算器を基本的なTTLだけで設計、製作しました。最終的には、TTLが30個でできました。。

ウラ面はこんな感じです。手ハンダなので、スパゲティボールです。

基板上の"Value A"と"Value B"のスイッチに-128から127までの数値を設定し、加算・減算した結果を"Result"LEDに表示します。負の数は2の補数表現です。

例えば、63＋1は、このようになります。

また、1+(-1)は、。

さらに、3-1は、。

回路図は、ここにあります。

CPUの中のALUの一部を解析するとこんな感じになるのでしょうね。

Modula-2 でプログラミング -- 文字列探索プログラム find の製作 (その３) --

Sun, 05 Jan 2025 21:19:30 +0900

前回紹介したfindプログラムは、FileSearchモジュールの不備で、ファイル一覧の構造が丸見えになっていました。FileSearchモジュールに２つ手続きを追加して不具合を解消しました。

新しいFileSearchモジュールの定義モジュールは以下の通り。


DEFINITION MODULE FileSearch;

FROM OpSys IMPORT FCB,FCBFileName;

EXPORT QUALIFIED pFileList,FileNameNode,
	GetNextFile,GetFileName,LoginDisk,MakeFileList,DumpFileList;

CONST
	DMABufferSize = 128;
	FileNameSize = 14;

TYPE
	pFileList = POINTER TO FileNameNode;
	FileNameNode = RECORD
		FileName: ARRAY [0..FileNameSize] OF CHAR;
		Next: pFileList
	END;
        DMA = ARRAY [0..DMABufferSize-1] OF CHAR;

PROCEDURE GetNextFile(FileLIst: pFileList): pFileList;
PROCEDURE GetFileName(FileList: pFileList;VAR FileName: ARRAY OF CHAR);
PROCEDURE LoginDisk(FCBBuf: FCB): CHAR;
PROCEDURE MakeFileList(FIleMatch: ARRAY OF CHAR): pFileList;
PROCEDURE DumpFileList(pList: pFileList);
END FileSearch.

手続き、次のファイルを取り出すGetNextFileとファイル名を取り出すGetFileNameを追加しました。実現モジュールは以下の通り。


IMPLEMENTATION MODULE FileSearch;
FROM InOut IMPORT WriteHex,Write,WriteString,WriteLn;
FROM OpSys IMPORT FCB,FCBFileName,BdosFunctions,Bdos;
FROM SYSTEM IMPORT ALLOCATE,TSIZE,ADR,WORD;
FROM FileNames IMPORT StrToFCB,FCBToStr,NameState;

CONST
	EOS = 0C;

PROCEDURE GetNextFile(FileList: pFileList): pFileList;
BEGIN
	RETURN FileList^.Next
END GetNextFile;

PROCEDURE GetFileName(FileList: pFileList; VAR FileName: ARRAY OF CHAR);
VAR
	i: CARDINAL; 
BEGIN
	i := 0;
	WHILE ( FileList^.FileName[i] # EOS ) DO
		FileName[i] := FileList^.FileName[i];
		INC(i)
	END;
	FileName[i] := EOS
END GetFileName;

PROCEDURE LoginDisk(FCBBuf: FCB): CHAR;
VAR
	DiskCode: CARDINAL;
	Junk: WORD;

BEGIN
	IF FCBBuf.name.disk = 0C THEN
		Bdos(retCDsk,Junk,DiskCode);
		RETURN (CHR(ORD(DiskCode)+ORD('A')));
	ELSE
		RETURN (CHR(ORD(FCBBuf.name.disk)+ORD('A')-1));
	END;
END LoginDisk;

PROCEDURE MakeFileList(FileMatch: ARRAY OF CHAR): pFileList;
VAR
	Disk: CHAR;
	FCBBuffer: FCB;
	BdosRc: CARDINAL;
	DMABuffer: DMA;
	CPos: CARDINAL;
	NameStatus: NameState;
	pList: pFileList;
	pNewFileName: pFileList;
	FCBFile: FCBFileName;
	Formatted: BOOLEAN;
	Junk: WORD;

BEGIN
	pList := NIL;

	(* Clear FCB Buffer and set file name *)
	FCBBuffer.name.text := '';
	FCBBuffer.rest := '';
	NameStatus := StrToFCB(FileMatch,FCBBuffer.name);

	Disk := LoginDisk(FCBBuffer);

	(* set DMA Bufer *)
	Bdos(setDMA,ADR(DMABuffer),Junk);

	(* find first much file *)
	Bdos(searchFst,ADR(FCBBuffer),BdosRc);
	WHILE BdosRc # 255 DO
		ALLOCATE(pNewFileName,TSIZE(FileNameNode));
		FOR CPos := 0 TO 11 DO
			FCBFile.text[CPos]
				:= DMABuffer[CPos+BdosRc*32]
		END;
		FCBFile.disk := CHR(ORD(Disk) - ORD('A') + 1);
		FCBToStr(FCBFile,pNewFileName^.FileName,FALSE);
		pNewFileName^.Next := pList;
		pList := pNewFileName;

		(* find next file *)
		Bdos(searchNxt,Junk,BdosRc);
	END;	
	RETURN pList
END MakeFileList;

PROCEDURE WriteFileName(FileName: ARRAY OF CHAR);
BEGIN
	WriteString(FileName);
	WriteLn
END WriteFileName;

PROCEDURE DumpFileList(pList: pFileList);
BEGIN
	WHILE pList # NIL DO
		WriteFileName(pList^.FileName);
		pList := pList^.Next;
	END;
END DumpFileList;
END FileSearch.

これらの変更を反映したfindは、以下のとおり。


MODULE Find;
FROM InOut IMPORT Write,WriteCard,WriteString,WriteLn;
FROM Files IMPORT FILE,FileState,Open,Close,Read;
FROM CmdArgs IMPORT Argc,Argv;
FROM FileSearch IMPORT GetFileName,GetNextFile,
	FileNameNode,MakeFileList,pFileList;
FROM BasicFileIO IMPORT FileIOStruct,pFileIOStruct,
	OpenFile,CloseFile,EOFFile,FileIOStatus;
FROM StdFileIO IMPORT GetLine;

CONST
	EOS = 0C;
	MAXLINE = 128;
	FILENAMESIZE = 14;
	EOFMARK = 32C;

VAR
	FileName: ARRAY [0..FILENAMESIZE] OF CHAR;
	FileMatch: ARRAY [0..FILENAMESIZE] OF CHAR;
	Target: ARRAY [0..MAXLINE] OF CHAR;
	CPos,FileNumber,LineNumber,nArgc: CARDINAL;
	pList: pFileList;

PROCEDURE putLine(FileName:ARRAY OF CHAR;Line:CARDINAL;
		Buffer: ARRAY OF CHAR);
BEGIN
	WriteString(FileName);
	Write(' ');WriteCard(Line,1);Write(':');
	WriteString(Buffer);
	WriteLn
END putLine;

PROCEDURE findTarget(Target,Line:ARRAY OF CHAR): BOOLEAN;
VAR
	t,l: CARDINAL;
	found: BOOLEAN;
BEGIN
	found := FALSE;
	t := 0; l := 0;
	WHILE (Line[l] # EOS) AND (NOT found) DO
		IF Line[l] = Target[0] THEN
			t := 1;
			WHILE Line[l+t] = Target[t] DO
				INC(t);
			END;
			IF Target[t] = EOS THEN
				found := TRUE;
			END;
		END;
		INC(l);
	END;
	RETURN found
END findTarget;

PROCEDURE Usage();
BEGIN
	WriteString('find');WriteLn;
	WriteString('      TargetString File1 File2 FIle3,,,,');WriteLn 
END Usage;

PROCEDURE MatchLines(FileName,TargetString: ARRAY OF CHAR);
VAR
	pFileIO: pFileIOStruct;
	Line: ARRAY [0..MAXLINE-1] OF CHAR;
	Chars: CARDINAL;
	NLines: CARDINAL;
	Junk: FileIOStatus;

BEGIN
	IF OpenFile(FileName,pFileIO) = Success THEN
		NLines := 1;
		WHILE NOT EOFFile(pFileIO) DO
			Chars := GetLine(pFileIO,Line);
			IF findTarget(TargetString,Line) THEN
				putLine(FileName,NLines,Line);
			END;
			INC(NLines);
		END;
		Junk := CloseFile(pFileIO)
	END
END MatchLines;

BEGIN
	nArgc := Argc();
	IF nArgc < 1 THEN
		Usage();
		HALT
	END;
	Argv(0,Target);
	FileNumber := 1;
	WHILE FileNumber < nArgc DO
		Argv(FileNumber,FileMatch);
		pList := MakeFileList(FileMatch);
		WHILE pList # NIL DO
			GetFileName(pList,FileName);
			MatchLines(FileName,Target);
			pList := GetNextFile(pList)
		END;
		INC(FileNumber)
	END
END Find.

これで、FileSearchモジュール内部のデータ構造をFindが知る必要がなくなりました。

Modula-2 でプログラミング -- 文字列探索プログラム find の製作 (その２)

Sat, 28 Dec 2024 21:13:31 +0900

BasicFileIO モジュール、StdFileIO モジュールをつかった find プログラムは、以下のとおりです。


MODULE Find;
FROM InOut IMPORT Write,WriteCard,WriteString,WriteLn;
FROM Files IMPORT FILE,FileState,Open,Close,Read;
FROM CmdArgs IMPORT Argc,Argv;
FROM FileSearch IMPORT pFileList,FileNameNode,MakeFileList;
FROM BasicFileIO IMPORT FileIOStruct,pFileIOStruct,
	OpenFile,CloseFile,EOFFile,FileIOStatus;
FROM StdFileIO IMPORT GetLine;

CONST
	EOS = 0C;
	MAXLINE = 128;
	FILENAMESIZE = 14;
	EOFMARK = 32C;

VAR
	FileMatch: ARRAY [0..FILENAMESIZE] OF CHAR;
	Target: ARRAY [0..MAXLINE] OF CHAR;
	CPos,FileNumber,LineNumber,nArgc: CARDINAL;
	pList: pFileList;

PROCEDURE putLine(FileName:ARRAY OF CHAR;Line:CARDINAL;
		Buffer: ARRAY OF CHAR);
BEGIN
	WriteString(FileName);
	Write(' ');WriteCard(Line,1);Write(':');
	WriteString(Buffer);
	WriteLn
END putLine;

PROCEDURE findTarget(Target,Line:ARRAY OF CHAR): BOOLEAN;
VAR
	t,l: CARDINAL;
	found: BOOLEAN;
BEGIN
	found := FALSE;
	t := 0; l := 0;
	WHILE (Line[l] # EOS) AND (NOT found) DO
		IF Line[l] = Target[0] THEN
			t := 1;
			WHILE Line[l+t] = Target[t] DO
				INC(t);
			END;
			IF Target[t] = EOS THEN
				found := TRUE;
			END;
		END;
		INC(l);
	END;
	RETURN found
END findTarget;

PROCEDURE Usage();
BEGIN
	WriteString('find');WriteLn;
	WriteString('      TargetString File1 File2 FIle3,,,,');WriteLn 
END Usage;

PROCEDURE MatchLines(FileName,TargetString: ARRAY OF CHAR);
VAR
	pFileIO: pFileIOStruct;
	Line: ARRAY [0..MAXLINE-1] OF CHAR;
	Chars: CARDINAL;
	NLines: CARDINAL;
	Junk: FileIOStatus;

BEGIN
	IF OpenFile(FileName,pFileIO) = Success THEN
		NLines := 1;
		WHILE NOT EOFFile(pFileIO) DO
			Chars := GetLine(pFileIO,Line);
			IF findTarget(TargetString,Line) THEN
				putLine(FileName,NLines,Line);
			END;
			INC(NLines);
		END;
		Junk := CloseFile(pFileIO)
	END
END MatchLines;

BEGIN
	nArgc := Argc();
	IF nArgc < 1 THEN
		Usage();
		HALT
	END;
	Argv(0,Target);
	FileNumber := 1;
	WHILE FileNumber < nArgc DO
		Argv(FileNumber,FileMatch);
		pList := MakeFileList(FileMatch);
		WHILE pList # NIL DO
			MatchLines(pList^.FileName,Target);
			pList := pList^.Next
		END;
		INC(FileNumber)
	END
END Find.

MachLine で、指定された文字列が読み込んだ行に存在するかを検査し、存在したら書き出します。

ファイル名のリスト構造が丸見えなのでひと工夫する必要がありますが、今回は見送りました。

Modula-2でプログラミング -- 文字列探索プログラム find の制作(その１)

Sat, 28 Dec 2024 21:00:39 +0900

指定された文字列を　指定されたファイルの中から探し出すプログラム find を紹介します。このように使います。


C0#find

arguments>GetLine *.def *.mod

C:STDFILEI.DEF 6:       GetLine;
C:STDFILEI.DEF 8:PROCEDURE GetLine(VAR pFileIO: pFileIOStruct;
C:STDFILEI.MOD 10:PROCEDURE GetLine(VAR pFileIO: pFileIOStruct;
C:STDFILEI.MOD 36:END GetLine;
C:FIND.MOD 8:FROM StdFileIO IMPORT GetLine;
C:FIND.MOD 71:                  Chars := GetLine(pFileIO,Line);


63K QP/M VER 2.7   (BIOS VER 1.0)

                   (C) 1988.12.1.  K.YOSHIDA

             2018.10.28.  MODEFIED BY H.KIDA
C0#find

arguments>GetChar *.def *.mod

C:BASICFIL.DEF 7:       ReadFile,GetChar;
C:BASICFIL.DEF 28:PROCEDURE GetChar(VAR pFileIO: pFileIOStruct): CHAR;
C:STDFILEI.MOD 3:       pFileIOStruct,GetChar;
C:STDFILEI.MOD 20:              C := GetChar(pFileIO);
C:BASICFIL.MOD 65:PROCEDURE GetChar(VAR pFileIO: pFileIOStruct): CHAR;
C:BASICFIL.MOD 89:END GetChar;


63K QP/M VER 2.7   (BIOS VER 1.0)

                   (C) 1988.12.1.  K.YOSHIDA

             2018.10.28.  MODEFIED BY H.KIDA
C0#

find は、ファイルを読みますので、ファイルアクセスのルーチンが必要になります。 Bdosを直接使うことができるので、かんたんなファイル読み込みモジュール BasicFileIO を作成しました。更に、行単位のファイル読み出しが必要なので、上位のモジュール StdFileIO を作成しました。StdFileIOは、 Bdosとは、独立しています。

まず、 BasicFileIO です。基本的なファイルアクセスルーチンの集まりです。今回は、読み出せれば良いので、書き込み関係のルーチンは作成していません。基本的なファイルのアクセスは、一文字単位です、定義モジュールは、以下のとおりです。


DEFINITION MODULE BasicFileIO;
FROM OpSys IMPORT FCB,FCBFileName;

EXPORT QUALIFIED 
	FileIOStatus,FileIOStruct,pFileIOStruct,
	OpenFile,CloseFile,EOFFile,
	ReadFile,GetChar;

CONST
	DMASize = 128;
TYPE
	FileIOStatus = (Success,InvalidFileName,
		OpenError,CloseError,IOError);
	DMA = ARRAY [0..DMASize-1] OF CHAR;
	pFileIOStruct = POINTER TO FileIOStruct;
	FileIOStruct = RECORD
		FCBBuf: FCB;
		DMABuf: DMA;
		ReadPos: CARDINAL;
		WritePos: CARDINAL;
		EOFFlag: BOOLEAN;
	END;

PROCEDURE OpenFile(FileName: ARRAY OF CHAR;
	VAR pFileIO: pFileIOStruct): FileIOStatus;
PROCEDURE CloseFile(VAR pFileIO: pFileIOStruct): FileIOStatus;
PROCEDURE ReadFile(VAR pFileIO: pFileIOStruct): FileIOStatus;
PROCEDURE GetChar(VAR pFileIO: pFileIOStruct): CHAR;
PROCEDURE EOFFile(pFileIO: pFileIOStruct): BOOLEAN;
END BasicFileIO.

実装モジュールは、以下のとおりです。手続き GetChar では、CR LF と連続した場合、 LF を読み飛ばします。


IMPLEMENTATION MODULE BasicFileIO;
FROM InOut IMPORT Write,WriteString,WriteLn;
FROM OpSys IMPORT BdosFunctions,FCBFileName,Bdos,FCB;
FROM FileNames IMPORT StrToFCB,NameState;
FROM SYSTEM IMPORT ALLOCATE,ADR,TSIZE,WORD;

CONST
	CR = 15C;
	LF = 12C;
	EOFMARK = 32C;

PROCEDURE OpenFile(FileName: ARRAY OF CHAR;
	VAR pFileIO: pFileIOStruct): FileIOStatus;
VAR
	BdosRc: CARDINAL;
	Junk: WORD;

BEGIN
	(* Allocate FCB and DMA / pre-Set *)
	ALLOCATE(pFileIO,TSIZE(FileIOStruct));
	pFileIO^.FCBBuf.name.text := '';
	pFileIO^.FCBBuf.rest := '';
	pFileIO^.DMABuf := '';
	IF StrToFCB(FileName,pFileIO^.FCBBuf.name) # NameOK THEN
		RETURN InvalidFileName
	END;
	Bdos(setDMA,ADR(pFileIO^.DMABuf),Junk);
	Bdos(openF,ADR(pFileIO^.FCBBuf),BdosRc);
	IF BdosRc # 255 THEN
		pFileIO^.ReadPos := DMASize;
		pFileIO^.WritePos := 0;
		pFileIO^.EOFFlag := FALSE;
		RETURN Success
	ELSE
		RETURN OpenError
	END
END OpenFile;

PROCEDURE CloseFile(VAR pFileIO: pFileIOStruct): FileIOStatus;
VAR
	BdosRc: CARDINAL;

BEGIN
	Bdos(closeF,ADR(pFileIO^.FCBBuf),BdosRc);
	IF BdosRc = 0 THEN
		RETURN Success
	ELSE
		RETURN CloseError
	END
END CloseFile;

PROCEDURE ReadFile(VAR pFileIO: pFileIOStruct): FileIOStatus;
VAR
	BdosRc: CARDINAL;

BEGIN
	Bdos(readSeq,ADR(pFileIO^.FCBBuf),BdosRc);
	IF BdosRc = 0 THEN
		RETURN Success
	ELSE
		RETURN IOError
	END
END ReadFile;

PROCEDURE GetChar(VAR pFileIO: pFileIOStruct): CHAR;
VAR
	C: CHAR;

BEGIN
	IF DMASize = pFileIO^.ReadPos THEN
		IF ReadFile(pFileIO) = Success THEN
			pFileIO^.ReadPos := 0
		ELSE
			pFileIO^.ReadPos := 0;
			pFileIO^.DMABuf[pFileIO^.ReadPos] := EOFMARK
		END
	END;
	C := pFileIO^.DMABuf[pFileIO^.ReadPos];
	IF C = CR THEN
		IF pFileIO^.DMABuf[pFileIO^.ReadPos+1] = LF THEN
			INC(pFileIO^.ReadPos)
		END
	END;
	INC(pFileIO^.ReadPos);
	IF C = EOFMARK THEN
		pFileIO^.EOFFlag := TRUE
	END;
	RETURN C
END GetChar;

PROCEDURE EOFFile(pFileIO: pFileIOStruct): BOOLEAN;
BEGIN
	RETURN pFileIO^.EOFFlag
END EOFFile;
END BasicFileIO.

GetChar で、 LF を読み飛ばす以外は、面倒くさいところは、ないでしょう。

この、 BasicFileIO モジュールをつかって、行単位の読み出しルーチンを作ってます。 StdFileIO モジュールです。このモジュールは、 CP/M のファイル構造と独立です。必要最低限の行単位の読み出ししか作成していません。

定義モジュールは、以下の通り。


DEFINITION MODULE StdFileIO;
FROM BasicFileIO IMPORT
	pFileIOStruct;

EXPORT QUALIFIED 
	GetLine;

PROCEDURE GetLine(VAR pFileIO: pFileIOStruct;
		VAR LineBuffer: ARRAY OF CHAR): CARDINAL;
END StdFileIO.

実装モジュールは、以下の通りです。


IMPLEMENTATION MODULE StdFileIO;
FROM BasicFileIO IMPORT
	pFileIOStruct,GetChar;

CONST
	EOS = 0C;
	EOFMARK = 32C;
	CR = 15C;

PROCEDURE GetLine(VAR pFileIO: pFileIOStruct;
		VAR LineBuffer: ARRAY OF CHAR): CARDINAL;

VAR
	C: CHAR;
	CPos: CARDINAL;

BEGIN
	CPos := 0;
	LOOP
		C := GetChar(pFileIO);
		CASE C OF
			EOFMARK:
				LineBuffer[CPos] := EOS;
				RETURN CPos
		|	CR:
				LineBuffer[CPos] := EOS;
				RETURN CPos
		END;
		LineBuffer[CPos] := C;
		INC(CPos);
		IF CPos = HIGH(LineBuffer) THEN
			LineBuffer[CPos] := EOS;
			RETURN CPos
		END
	END
END GetLine;
END StdFileIO.

GetLine は、一文字読み出しを繰り返し、 CR または EOF が来たら、その一文字前の文字までを一行とします。また、バッファーのサイズ以上に読み取ろうとした場合は、強制的に一行にしてしまいます。溢れてしまうと困りますので。

find 本体の紹介は次回にします。

Modula-2でプログラミング -- FileFindの制作

Sat, 02 Nov 2024 11:36:11 +0900

FIleSearche"モジュールを利用した、ファイマッチで指定されたファイル一覧を書き出すプログラム "FileFind"を作ってみました。

使い方は、このようにします。


C0#filefind
arguments>f*.mod *.def
C:FIND.MOD
C:FILEFIND.MOD
C:FILESEAR.MOD
C:CONIO.DEF
C:ADD16.DEF
C:SILLY.DEF
C:FILESEAR.DEF
C:STDFILEI.DEF
C:BDOSSTRU.DEF
C:BASICFIL.DEF
C:CMDARGS.DEF
C:SCREEN.DEF

探すファイル名は、ファイルマッチを指定できます。複数指定できます。この引数を受け取るには、以前紹介した自作の"CmdArgs"モジュールを使用しています。

プログラムは、このようになりました。


MODULE FileFind;
FROM InOut IMPORT WriteString,WriteLn;
FROM CmdArgs IMPORT Argc,Argv;
FROM FileSearch IMPORT MakeFileList,DumpFileList;

CONST
	MAXLINE = 128;

VAR
	FileMatch: ARRAY [0..MAXLINE-1] OF CHAR;
	nArgc: CARDINAL;
	NthFile: CARDINAL;

PROCEDURE Usage();
BEGIN
	WriteString('Usage: filefind filematch');WriteLn;
END Usage;

BEGIN
	nArgc := Argc();
	IF nArgc < 1 THEN
		Usage();
		HALT;
	END;

	NthFile := 0;
	WHILE NthFile < nArgc DO 
		Argv(NthFile,FileMatch);
		DumpFileList(MakeFileList(FileMatch));
		INC(NthFile);
	END;
END FileFind.

次々にファイルマッチを取り出し、該当するファイル名のリストを"MakeFileList"で作成し、そのリストを"DumpFileLIst"で書き出します。"DumpFileList"は、"FileSearch"モジュールに実装しました。こうすることで、ファイル名の保持のしかたをメインルーチンが知る必要がありません。

Modula-2でプログラミング -- FileSearch ファイルを探すモジュールの修正

Sat, 02 Nov 2024 10:29:22 +0900

前回、ファイルを探すモジュール"FileSearch"を制作しました。これを利用したプログラムをいくつか作成して見た所、ファイル名リストのデータ構造の使い勝手が良くないことがわかりましたので"FileSearch"モジュールを修正しました。

修正した"FileSearch"モジュールのDefinition Moduleです。


DEFINITION MODULE FileSearch;

FROM OpSys IMPORT FCB,FCBFileName;

EXPORT QUALIFIED pFileList,FileNameNode,DMA,
	LoginDisk,MakeFileList,DumpFileList;

CONST
	DMABufferSize = 128;
	FileNameSize = 14;

TYPE
	pFileList = POINTER TO FileNameNode;
	FileNameNode = RECORD
		FileName: ARRAY [0..FileNameSize] OF CHAR;
		Next: pFileList
	END;
        DMA = ARRAY [0..DMABufferSize-1] OF CHAR;

PROCEDURE LoginDisk(FCBBuf: FCB): CHAR;
PROCEDURE MakeFileList(FIleMatch: ARRAY OF CHAR): pFileList;
PROCEDURE DumpFileList(pList: pFileList);
END FileSearch.

大きな変更点は、ファイル名の持ち方をべたな文字列にした点です。

修正したImprementation Moduleは、このとおり。


IMPLEMENTATION MODULE FileSearch;
FROM InOut IMPORT WriteHex,Write,WriteString,WriteLn;
FROM OpSys IMPORT FCB,FCBFileName,BdosFunctions,Bdos;
FROM SYSTEM IMPORT ALLOCATE,TSIZE,ADR,WORD;
FROM FileNames IMPORT StrToFCB,FCBToStr,NameState;

CONST
	EOS = 0C;

PROCEDURE LoginDisk(FCBBuf: FCB): CHAR;
VAR
	DiskCode: CARDINAL;
	Junk: WORD;

BEGIN
	IF FCBBuf.name.disk = 0C THEN
		Bdos(retCDsk,Junk,DiskCode);
		RETURN (CHR(ORD(DiskCode)+ORD('A')));
	ELSE
		RETURN (CHR(ORD(FCBBuf.name.disk)+ORD('A')-1));
	END;
END LoginDisk;

PROCEDURE MakeFileList(FileMatch: ARRAY OF CHAR): pFileList;
VAR
	Disk: CHAR;
	FCBBuffer: FCB;
	BdosRc: CARDINAL;
	DMABuffer: DMA;
	CPos: CARDINAL;
	NameStatus: NameState;
	pList: pFileList;
	pNewFileName: pFileList;
	FCBFile: FCBFileName;
	Formatted: BOOLEAN;
	Junk: WORD;

BEGIN
	pList := NIL;

	(* Clear FCB Buffer and set file name *)
	FCBBuffer.name.text := '';
	FCBBuffer.rest := '';
	NameStatus := StrToFCB(FileMatch,FCBBuffer.name);

	Disk := LoginDisk(FCBBuffer);

	(* set DMA Bufer *)
	Bdos(setDMA,ADR(DMABuffer),Junk);

	(* find first much file *)
	Bdos(searchFst,ADR(FCBBuffer),BdosRc);
	WHILE BdosRc # 255 DO
		ALLOCATE(pNewFileName,TSIZE(FileNameNode));
		FOR CPos := 0 TO 11 DO
			FCBFile.text[CPos]
				:= DMABuffer[CPos+BdosRc*32]
		END;
		FCBFile.disk := CHR(ORD(Disk) - ORD('A') + 1);
		FCBToStr(FCBFile,pNewFileName^.FileName,FALSE);
		pNewFileName^.Next := pList;
		pList := pNewFileName;

		(* find next file *)
		Bdos(searchNxt,Junk,BdosRc);
	END;	
	RETURN pList
END MakeFileList;

PROCEDURE WriteFileName(FileName: ARRAY OF CHAR);
BEGIN
	WriteString(FileName);
	WriteLn
END WriteFileName;

PROCEDURE DumpFileList(pList: pFileList);
BEGIN
	WHILE pList # NIL DO
		WriteFileName(pList^.FileName);
		pList := pList^.Next;
	END;
END DumpFileList;
END FileSearch.

大きな修正点は、見つかったファイルの名前をFCB形式からべたな文字列のファイル名に変換し、それを保存している点です。ファイル名の持ち方をべたな文字列にしたので、ファイル名を書き出すPROCEDURE "WriteFileName"を修正しています。

他には、"BdosStruct"モジュールの使用をやめました。処理系が提供する Bdos関連機能の"OpSys"モジュールを一部修正し、"BdosStruct"モジュールが無くてもコンパイルできるようにしました。

Modula-2でプログラミング -- FileSearch ファイルを探すモジュールの制作

Sat, 19 Oct 2024 09:49:50 +0900

ファイルを探すことは、結構よくあることです。CP/Mでプログラムを作る場合でも同じこと。今回は、Modula-2からBDOSの機能を呼び出し、ファイルを探す"FileSearch"モジュールを紹介します。

"FileSearch"モジュールは、処理系が提供するモジュールをいくつか使用しています。

"OpSys"モジュールは、BDOSやBIOSを呼び出すためのBdos手続きやFCBなどのレコード型などを提供しています。
"FileNames"モジュールは、FCBのファイル名領域にファイル名を設定する手続きや、その手続きの戻り値の型を提供しています。
"SYSTEM"モジュールは、メモリーの動的確保や変数のサイズなどを調べる手続きを提供しています。

このほかに自作モジュール"BdosStruct"があります。これは、BDOSを呼び出すBdos手続きがちょっと使いにくかったので、処理系を騙す仕組みを作り込みました。

"FileSearch"モジュールのDefinition Moduleです。


DEFINITION MODULE FileSearch;

FROM InOut IMPORT Write,WriteString,WriteLn;
FROM OpSys IMPORT FCB,CPMStringBuffer,BdosFunctions,Bdos;
FROM SYSTEM IMPORT ALLOCATE,SIZE,ADR,WORD;
FROM FileNames IMPORT StrToFCB,NameState;
FROM BdosStruct IMPORT BdosCommand,BdosReturn;

EXPORT QUALIFIED pFileList,FileList,FileStruct,DMA,
        LoginDisk,MakeFileList,DumpFileList;

CONST
        DMABufferSize = 128;

TYPE
        FileStruct = RECORD
                CASE BOOLEAN OF
                        TRUE:   Disk: CHAR;
                                Fill1: CHAR;
                                Name: ARRAY [0..7] OF CHAR;
                                Fill2: CHAR;
                                Extention: ARRAY [0..2] OF CHAR;
                |       FALSE:  Text: ARRAY [0..13] OF CHAR;
                END;
        END;
        pFileList = POINTER TO FileList;
        FileList = RECORD
                File: FileStruct;
                Next: pFileList;
        END;
        DMA = ARRAY [0..DMABufferSize-1] OF CHAR;

PROCEDURE LoginDisk(FCBBuf: FCB): CHAR;
PROCEDURE MakeFileList(FileMatch: ARRAY OF CHAR): pFileList;
PROCEDURE DumpFileList(pList: pFileList);
END FileSearch.

Imprementation Moduleは、このとおり。


IMPLEMENTATION MODULE FileSearch;

FROM InOut IMPORT Write,WriteString,WriteLn;
FROM OpSys IMPORT FCB,BdosFunctions,Bdos;
FROM SYSTEM IMPORT ALLOCATE,SIZE,ADR,WORD;
FROM FileNames IMPORT StrToFCB,NameState;
FROM BdosStruct IMPORT BdosCommand,BdosReturn,FileStruct,DMA;

PROCEDURE LoginDisk(FCBBuf: FCB): CHAR;
VAR
        BdosCmd: BdosCommand;
        Junk: WORD;
        DiskCode: BdosReturn;

BEGIN
        IF FCBBuf.name.disk = 0C THEN
                BdosCmd.Func := retCDsk;
                Bdos(BdosCmd.Cmd,Junk,DiskCode.Rc);
                RETURN (CHR(ORD(DiskCode.Cc)+ORD('A')));
        ELSE
                RETURN (CHR(ORD(FCBBuf.name.disk)+ORD('A')-1));
        END;
END LoginDisk;

PROCEDURE MakeFileList(FileMatch: ARRAY OF CHAR): pFileList;
VAR
        Disk: CHAR;
        FCBBuffer: FCB;
        BdosFunc: BdosCommand;
        BdosRc: BdosReturn;
        DMABuffer: DMA;
        ToPos, FromPos: CARDINAL;
        NameStatus: NameState;
        pList: pFileList;
        pNewFile: pFileList;
        NewFile: FileList;
        Junk: WORD;

BEGIN
        (* Clear FCB Buffer and set file name *)
        FCBBuffer.name.text := '';
        FCBBuffer.rest := '';
        NameStatus := StrToFCB(FileMatch,FCBBuffer.name);

        (* get target disk *)
        Disk := LoginDisk(FCBBuffer);

        (* set DMA Bufer *)
        BdosFunc.Func := setDMA;
        Bdos(BdosFunc.Cmd,ADR(DMABuffer),Junk);

        (* initialize File Name List pointer *)
        pList := NIL;

        (* find first much file *)
        BdosFunc.Func := searchFst;
        Bdos(BdosFunc.Cmd,ADR(FCBBuffer),BdosRc.Rc);
        WHILE BdosRc.Cc # 255 DO
                (* copy from FCB buffer to file struct *)
                ALLOCATE(pNewFile,SIZE(NewFile));
                pNewFile^.File.Disk := Disk;
                pNewFile^.File.Fill1 := ':';
                ToPos := 0;
                FOR FromPos := 1 TO 8 DO
                        pNewFile^.File.Name[ToPos] 
                                := DMABuffer[FromPos+BdosRc.Cc*32];
                        INC(ToPos);
                END;

                pNewFile^.File.Fill2 := '.';
                ToPos := 0;
                FOR FromPos := 9 TO 11 DO
                        pNewFile^.File.Extention[ToPos]
                                := DMABuffer[FromPos+BdosRc.Cc*32];
                        INC(ToPos);
                END;
                (* insert new one *)
                pNewFile^.Next := pList;
                pList := pNewFile;

                (* find next file *)
                BdosFunc.Func := searchNxt;
                Bdos(BdosFunc.Cmd,Junk,BdosRc.Rc);
        END;    
        RETURN pList
END MakeFileList;

PROCEDURE WriteFileStruc(FileStruc: FileStruct);
BEGIN
        Write(FileStruc.Disk);
        Write(FileStruc.Fill1);
        WriteString(FileStruc.Name);

        Write(FileStruc.Fill2);
        WriteString(FileStruc.Extention);
        WriteLn;
END WriteFileStruc;

PROCEDURE DumpFileList(pList: pFileList);
BEGIN
        WHILE pList # NIL DO
                WriteFileStruc(pList^.File);
                pList := pList^.Next;
        END;
END DumpFileList;

END FileSearch.

MakeFileList手続きが処理の中心です。ファイルを探すにはBDOSの機能番号１６最初のデータを探す(SearchFirst)、機能番号１７次にデータを探す(SearchNext)を使います。はじめに、FCBとDMAを準備します。そして、FCB領域を初期化します。


        (* Clear FCB Buffer and set file name *)
        FCBBuffer.name.text := '';
        FCBBuffer.rest := '';
        NameStatus := StrToFCB(FileMatch,FCBBuffer.name);

ここで躓きました。"FCBBuffer.rest"を初期化をしなかったために、最初のデータを取得できたりできなかったりと、動作が不安定でした。アセンブラでテストルーチンを書くとうまく動作します。悩みました。使用したアセンブラでは、確保したデータ領域を自動的に0を埋め込んでいました。しかし、Modula-2処理系では領域内の値は不定になるため、動作がおかしくなった様です。

最初のデータを見つけてしまえば、後は順に見つけることができました。

見つけたファイル名をリスト構造にして、返します。

DumpFileList手続きは、ファイル名リストを表示します。下受けルーチンとして、WriteFileStruc手続きを使っています。

特に難しいロジックはありません。

BdosStructは、Definition Moduleだけです。以下のようになっています。


DEFINITION MODULE BdosStruct;

FROM OpSys IMPORT BdosFunctions;
FROM SYSTEM IMPORT WORD;

EXPORT QUALIFIED
        BdosCommand,BdosReturn;2

TYPE
        BdosCommand = RECORD
                CASE BOOLEAN OF
                        TRUE:   Func: BdosFunctions;
                |       FALSE:  Cmd: WORD;
                END;
        END;
        BdosReturn = RECORD
                CASE BOOLEAN OF
                        TRUE:   Rc: WORD;
                |       FALSE:  Cc: CARDINAL;
                END;
        END;
END BdosStruct.

次回は、これを応用したファイルマッチで指定されたファイルをリストするコマンド"FileFind"紹介します。

TIのTL497を使ったStep-Down コンバーターの制作

Sun, 21 Apr 2024 09:10:23 +0900

自作のボードコンピュター用に、出力16VのACアダプターをTA7805で5Vに落とした電源器を使っていました。とても発熱がとてもひどいので、対策を考えていました。今回は、TIのスイッチングレギュレータ用IC TL497を使ったStep-Downコンバーターを使って、発熱の少ない電源を作ってみました。

TL497をStep-Downコンバータとして使うのは、初めてなので３タイプを制作してみました。

TL497単体で制作した、12V入力で5V/0.5A出力の電源
上の回路に外付けトランジスタを追加して出力電流を多くした電源
更に、入力電源電圧を16V用にした電源。TL497の最大電源電圧は15Vなのでひと工夫が必要です。

まずは、TL497単体で制作した電源です。回路図と外観はこのとおり。 (手持ちのパーツを使用したため、一部に大げさな規格のパーツを使用しています。)

回路はデータシートどおりです。

外付けトランジスタを追加して出力電流を増やしました。これで、1Aまで取れます。

15V以上の入力電圧に対応できるようにしたのが、これです。入力電圧を78L12で受けてTL497の電源にしています。実際に長時間連続で使用しても発熱は少なくなり、当初の目的を達成できました。

ヴィルト先生

Sat, 06 Jan 2024 13:10:54 +0900

チューリッヒ連邦工科大学のOberonチームから、悲しい知らせが届きました。Pascal, Modulaといったプログラミング言語を世に送り出し、更にOberonという言語で記述したテキスト指向のオペレーティングシステムの開発者でもあるニクラウス　ヴィルト先生が、なくなりました。

私が、ヴィルト先生のことを知ったのは、学生時代に参加したPascalの勉強会ででした。使用したテキストが、ヴィルト先生らが書いた「Pascal(原題 Pascal User Manual and Report)」でした。この勉強会を通じて、Fortranとは違うプログラミング・パラダイムを知り、構造化されたプログラミングスタイルを身につけることができました。このことは、仕事についてから、Cでのプログラム開発に、大いに役立ちました。また、その後の、仕事においても、趣味においてでも、Pascalは重要な位置を締めてきました。

ヴィルト先生の著作を　もう２冊持っています。「アルゴリズム＋データ構造＝プログラム(原題 ALGORITHMS+DATA STRUCTURES=PROGRAM)」と「アルゴリズムとデータ構造(原題 ALGORITHMS & DATA STRUCTURES)」です。この２冊は兄弟になる著作でしょう。前者は、Pascalで、後者はModula-2でアルゴリズムの選択やそれに適したデータ構造の構築について議論がなされています。これら３冊は、私にとってバイブル的存在であり、すぐに手に取れるところにおいています。

私がプログラマーとして成長するのに、大きな影響を受けたヴィルト先生のご冥福をお祈りましす。

ASSIT09で、8-Queens

Thu, 21 Dec 2023 17:18:28 +0900

8-Queensを解くプログラムです。これは、8x8のマスにお互いが鑑賞しないようにQueenのコマの配置を求めるプログラムです。オリジナルで作成しようと頑張ったのですが、行き詰まってしまいました。いつものように、先人の方々のお知恵を拝借しました。調べてみると、ヴィルトの「アルゴリズム＋データ構造＝プログラム」にPascalで書かれたスマートな解がありました。暑中参照している「マイクロコンピュータのプログラミング」にもMicroPlanでの解が掲載されています。このMicroPlanの解を参照して、プログラムを作成しました。

さて、下敷きにしたプログラムは、Queenの配置を求めるルーチンが再帰的に書かれています。これをMC6809のアセンブラで書き下すのがキーポイントでしょう。想像しているより簡単に実現できました。MC6809にはスタックが、システムスタック Sとユーザースタック Uの2つがあります。このユーザースタックに、再帰的関数内部のローカル変数を退避させることでうまく行きました。プログラム、アセンブルリスト、実行結果などは、こちらです。 8Queen.zip

いつものように、Lコマンドでロード・モジュールをダウンロードし、Cコマンドで、C000から実行させます。

Queenの配置が、次々と出てきます。


         === 8 Queens ===
           0 4 7 5 2 6 1 3
           0 5 7 2 6 3 1 4
           0 6 3 5 7 1 4 2
           0 6 4 7 1 3 5 2
           1 3 5 7 2 0 6 4
           1 4 6 0 2 7 5 3
           1 4 6 3 0 7 5 2
                  :
                  :
                  :

例えば、"0 4 7 5 2 6 1 3"は、


          カラム 0のQueenは、ロウ 0に
          カラム 1のQueenは、ロウ 4に
          カラム 2のQueenは、ロウ 7に
          カラム 3のQueenは、ロウ 5に
          カラム 4のQueenは、ロウ 2に
          カラム 5のQueenは、ロウ 6に
          カラム 6のQueenは、ロウ 1に
          カラム 7のQueenは、ロウ 3に

にあることを示しています。こんな配置です。


            0 1 2 3 4 5 6 7
          0 Q . . . . . . .
          1 . . . . . . Q .
          2 . . . . Q . . .
          3 . . . . . . . Q
          4 . Q . . . . . .
          5 . . . Q . . . .
          6 . . . . . Q . .
          7 . . Q . . . . .